Intervallfotografie im Zeitfenster über mehrere Tage

DRI/HDR-Bilder, Zeitraffer, Bilder mit extremer Tiefenschärfe, Stereobilder

Intervallfotografie im Zeitfenster über mehrere Tage

Beitragvon fotofrickler » 07.08.2008, 19:05

Ich habe ein Script geschrieben, mit dem man in einem bestimmten Zeitfenster die Fotos für Zeitraffervideos aufnehmen lassen kann.

Man stellt die Startzeit und die Stopzeit ein und Zeit zwischen 2 Fotos, also z.B. "mache im Zeitfenster zwischen 5:00 und 8:00 alle 10 Sekunden ein Bild". Ist praktisch, wenn man einen Sonnenaufgang zeitraffen will aber keine Lust hat, um 5:00 aufzustehen. Das macht die Kamera nun von selber.

Das Ganze funktioniert auch über mehrere Tage. Das Script macht immer dann die Fotos, wenn die kamera-eigene Uhrzeit in das Zeitfenster fällt. In der restlichen Zeit macht sie außer warten nicht. Für solche Ultra-Langzeit-Aufnahmen ist ein Netzteil oder ähnliches nötig, da die kleinen Akkus für so etwas nicht ausreichen.

Das Zeitfenster funktioniert sogar auch über Mitternacht, also wer die Sterne zwischen 22:00 und 4:00 fotografieren will, geht auch.

Falls beim Start die Kamerazeit in das Zeitfenster fällt, fängt die Kamera sofort an.

Code: Alles auswählen
rem Zeitraffer im Zeitfenster
rem allbest 51 ab Build 144

@title ZR Zeitfenster
@param a Startzeit (Std.)
@default a 0
@param b Startzeit (Min.)
@default b 0
@param c Startzeit (Sek.)
@default c 0
@param d Intervall (Min.)
@default d 0
@param e Intervall (Sek.)
@default e 0
@param f Stopzeit (Std.)
@default f 0
@param g Stopzeit (Min.)
@default g 0
@param h Stopzeit (Sek.)
@default h 0

rem schneller als alle 3 Sekunden geht nicht mit diesem Script (S2IS)
z=(d*60)+e
if z<3 then z=3

x=get_day_seconds
y=x/60
H=y/60
M=y-(H*60)
S=x-(y*60)

rem kurze Anzeige der Einstellungen
print "es ist",H,":",M,":"S
print "starte",a,":",b,":"c
print "stoppe",f,":",g,":"h
print "Fotos alle",z,"Sek."
sleep 4000
cls

rem Anfangs- und Endzeit berechnen
A=(a*3600)+(b*60)+c
E=(f*3600)+(g*60)+h

gosub "lcd_off"

if A>E then goto "nachts"

:tags
Z=get_day_seconds
if A<Z and Z<E then goto "loop1"
:init1
Z=A
:loop1
sleep 100
t=get_day_seconds
if t<A or E<t then goto "init1"
if t<Z then goto "loop1"
shoot
Z=Z+z
goto "loop1"

:nachts
Z=get_day_seconds
if Z<E or A<Z then goto "loop2"
:init2
Z=A
:loop2
sleep 100
t=get_day_seconds
if E<t and t<A then goto "init2"
if t<Z then goto "loop2"
shoot
Z=Z+z
goto "loop2"

:lcd_off
rem Hier Code einfügen um LCD auszuschalten
return

end


Have fun
Dateianhänge
zr_timer.bas
Das obige Script noch einmal für den Download
(1.32 KiB) 418-mal heruntergeladen
S2 IS
Firmware GM 1.00F
CHDK 0.8.4-595
SanDisk Extreme III 2GB
Kingston 2GB
fotofrickler
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 23
Registriert: 29.05.2008, 20:19
Wohnort: Schwarzwald

Zurück zu kreative Arbeit mit dem CHDK

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 12 Gäste

cron