[gelöst] Script zu Bewegungserkennung lässt chdk abstürzen

Fragen zur Bedienung und Funktionsweise des CHDKs
Forumsregeln
Überprüfe folgende Dinge:
Bist stets der Dokumentation gefolgt?
Hast du im Forum schon nach ähnlichen Problemen gesucht?
Hast du bei deiner Frage das Problem umfassend beschrieben?
Welche Kamera und CHDK-Version betrifft das Problem?

Probleme mit einem Skript sollten möglichst und wenn vorhanden in dem zugehörigen Thema zum Skript besprochen werden.

Script zu Bewegungserkennung lässt chdk abstürzen

Beitragvon KHW » 09.04.2009, 17:47

Hallo,
Habe seit längerem wieder einmal mit einem älteren Bewegungs-script experimentiert.
Dabei passierte bei meiner A720 IS fogendes.
Wenn ich einen kleinen Font als Schrift habe funktioniert alles normal, da ich aber nicht mehr der Jüngste bin habe ich eine großeSchriftart (arial 20b) eingestellt. (passiert auch mit Libsans20) .
Mit der großen Schriftart hängt sich die kamera auf.
Ich kann weder den alt-Modus verlassen noch die Kamera ausschalten .?

Was ich nicht verstehe ist. das das Script mit einer kleinen Schriftart problemlos funktioniert???
Ich benutze das neueste CHDK 729 und das schon ältere Bas -scipt

rem Developed on A570IS (Digic III) by fudgey. This variant may work on all Digic II cameras.
rem Allbest build 34 or higher (or compatible md_detect_motion) is required.
rem Digic III needs a small modification: "get_prop 205 p" -> "get_prop 206 p"
@title Fast MD Burst/Review + Mask 080411
@param a Columns
@default a 6
@param b Rows
@default b 4
@param c Threshold (0-255)
@default c 10
@param g Burst/Review time (s)
@default g 0
@param d Compare Interval (ms)
@default d 7
@param h Pixel Step (pixels)
@default h 6
@param f Channel (0U,1Y,2V,3R,4G,5B)
@default f 1
@param n Timeout (10s of seconds)
@default n 30
@param e Trigger Delay (0.1 sec)
@default e 5
@param i Masking (0=No 1=Mask 2=Use)
@default i 0
@param j Mask Columns Left
@default j 0
@param k Mask Columns Right
@default k 0
@param l Mask Rows Top
@default l 0
@param m Mask Rows Bottom
@default m 0
@param o Slow Shoot (0=No 1=Yes)
@default o 0
if a<1 then a=1
if b<1 then b=1
if i<0 then i=0
if i>2 then i=2
if j<0 then j=0
if k<0 then k=0
if l<0 then l=0
if m<0 then m=0
if j>a then j=a
if k>a then k=a
if l>b then l=b
if m>b then m=b
if g<0 then g=0
if f<0 then f=1
if f>5 then f=1
if f=0 then print "Channel: U chroma"
if f=1 then print "Channel: Luminance"
if f=2 then print "Channel: V chroma"
if f=3 then print "Channel: Red"
if f=4 then print "Channel: Green"
if f=5 then print "Channel: Blue"
if n<1 then n=1
e=e*100
g=g*1000
n=n*10000
if o>0 then goto "slow_md_loop"
:fast_md_loop
press "shoot_half"
t=0
do
do
get_prop 206 p
until p=1
md_detect_motion a, b, f, n, d, c, 1, t, i, j+1, l+1, a-k, b-m, 9, h, e
until t>0
let X=get_tick_count
:contloop1
let U=get_tick_count
let V=(U-X)
if V<g then goto "contloop1"
release "shoot_full"
do
get_prop 206 p
until p<>1
goto "fast_md_loop"
:slow_md_loop
t=0
do
md_detect_motion a, b, f, n, d, c, 1, t, i, j+1, l+1, a-k, b-m, 0, h, e
until t>0
if g>1 then goto "contshoot2" else shoot
goto "slow_md_loop"
:contshoot2
press "shoot_full"
let X=get_tick_count
:contloop2
let U=get_tick_count
let V=(U-X)
if V<g then goto "contloop2"
release "shoot_full"
do
get_prop 206 p
until p<>1
goto "slow_md_loop"


Wäre interessant zu wissen ob es wirklich nur mit der Schriftart zusammenhängt oder ob das Script zu alt ist und somit nicht mehr kompatibel ist..
A 720 IS (aktuelle CHDK version)
KHW
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 9
Registriert: 09.04.2009, 08:55
Wohnort: Rimbach

Beitragvon msl » 09.04.2009, 22:35

Hallo,

es liegt nur mittelbar am Skript.

Bei der großen Schriftart kann der Skript-Titel nicht sauber verarbeitet werden, weil er in diesem Fall zu lang ist.

Ändere

@title Fast MD Burst/Review + Mask 080411

in

@title Fast MD Burst

Dann funktioniert das Skript auch bei einem 20er Font.

Gruß msl
Benutzeravatar
msl
Super-Mod
Super-Mod
 
Beiträge: 4567
Bilder: 271
Registriert: 22.02.2008, 11:47
Wohnort: Leipzig
Kamera(s): A720 1.00c
SX220 1.01a

Beitragvon KHW » 10.04.2009, 06:45

Hallo msl,
Vielen Dank für die schnelle Antwort.

Es funktioniert jetzt wieder problemlos.

ist ja doch einfach wenn man es weiß!!!

Danke
A 720 IS (aktuelle CHDK version)
KHW
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 9
Registriert: 09.04.2009, 08:55
Wohnort: Rimbach


Zurück zu Probleme

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 16 Gäste