[uBasic] Shoot Problem - Scriptanpassung ixus 55

CHDK-Skripte, CHDK-Entwicklung, PC-Zusatzprogramme, Informationen für Tüftler

Shoot Problem - Scriptanpassung ixus 55

Beitragvon pi23 » 24.06.2008, 20:11

Das Problem ist ja bei mehreren Kameras der 10er Serie bekannt. Die Kamera (bei mir ixus 55) bleibt nach dem ersten "Shoot" Befehl stehen.
Die Lösung bei manchen Scripts den "Shoot" Befehl durch:

Code: Alles auswählen
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"


ersetzen.

Das hat bei mir bei folgenden Scripts funktioniert.
Code: Alles auswählen
@title Intervall-Fotografie

@param a Zahl der Aufnahmen
@default a 100
@param b Intervall (Min.)
@default b 0
@param c Intervall (Sek.)
@default c 1

t=b*60000+c*1000

if a<2 then let a=10
if t<1000 then let t=1000

print "Gesamtzeit:", t*a/60000, "Min.", t*a%60000/1000, "Sek."

sleep 1000

print "Aufnahme 1 von", a
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
for n=2 to a
    print "Warte", b, "Min.", c, "Sek."
    sleep t
    print "Aufnahme", n, "von", a
    press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
next n

end


Code: Alles auswählen
@title Belichtungsreihe
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1

if a<1 then a=3
if b<1 then b=5
if c<0 then c=0

if c>0 then print "Warte", c, "Sekunden"
sleep c*1000

get_prop 25 x
y=-(a*b+a)*16
for s=1 to b
y=y+a*32
set_prop 25 y
set_prop 26 y
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"von",b,"mit",z","(y*10/32/3-z*10)*t,"EV"
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
release "shoot_half"
sleep 500
next s
set_prop 25 x
set_prop 26 x
end


Code: Alles auswählen
@title Belichtungsreihe fix Fokus
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1

rem Ueberpruefung mind. 1 EV Step
if a<1 then a=3
rem Ueberpruefung auf mehr als 1 Bild
if b<1 then b=5
rem keine neg. Verzögerung
if c<0 then c=0

if c>0 then print "Warte", c, "secunden"
sleep c*1000

rem Belichtungskorrektur lesen und in u,v speichern
get_prop 25 u
get_prop 26 v

rem fokussieren und Fokus speichern
press "shoot_half"
sleep 2000
get_focus q
release "shoot_half"

y=-(a*b+a)*16
for s=1 to b
y=y+a*32
rem Belichtungskorrektur setzen
set_prop 25 y
set_prop 26 y
rem Fokus pruefen und ggf. auf ermittelten Wert setzen
get_focus r
if r<>q then
set_focus q
endif
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
click "shoot_full"
rem ...warten, bis das Bild gespeichert ist
do
get_prop 205 w
until w=1
do
get_prop 205 w
until w<>1
next s

rem urspruengliche Belichtungskorrektur wieder herstellen
set_prop 25 u
set_prop 26 v
end



Nun zu den Scripts bei denen es (noch) nicht geht.

Code: Alles auswählen
@title Bewegungserkennung
@param a Spalten
@default a 6
@param b Reihen
@default b 4
rem Schwellwert: 10=Blitz, 12=sonnig, 24=wolkig, 36=dunstig
rem Der Schwellwert ist die Epfindlichkeit der Bewegungserkennung
rem Blitz steht für Gewitterfotografie
@param c Schwellwert(0-255)
@default c 24
@param d Interval (mSek.)
@default d 1
rem Verzögerung: 0=sehr schnell(Blitz), 16=normal, 32=langsam
@param e Verzögerung(.1 Sek.)
@default e 0
@param f Blockgröße
@default f 8
rem Modus U bzw.V=chroma Y=luma
@param g Modus(U=0,Y=1,V=2)
@default g 1
@param h Anfangsverzögerung (Sek.)
@default h 1

if a<1 then a=1
if b<1 then b=1
if c<0 then c=0
if e<0 then e=0
if f<1 then f=1
if g<0 then g=0
if g>5 then g=5
if r<0 then r=0
if h<0 then h=0

e=e*100

rem Startzeit in ms
x=5000

sleep h*1000

i=0
while 1
t=0
if e=0 then
press "shoot_half"
do
rem Digic II 205 Digic III 206
get_prop 205 p
until p=1
endif
md_detect_motion a, b, g, x, d, c, 1, t, 0, 1, 1, a, b, 0, f, e
if t>0 then
click "shoot_full"
sleep 1000
release "shoot_full"
i=i+1
print "Bild", i, "(Blocks="; t; ")"
if e=0 then
do
rem Digic II 205 Digic III 206
get_prop 205 p
until p<>1
endif
endif
wend


Hier wird einaml ausgelößt dann bleibt das Script stehen. Wo liegt der Fehler?

Und Hier:

Code: Alles auswählen
@title Intervall_HDR
rem HDR_Param
@param a HDR_Stellweite
@default a 3
@param b Anzahl Fotografien max. 13
@default b 5
rem Intevall_Param
@param c Zahl der Aufnahmen
@default c 3
@param d Intervall (min)
@default d 0
@param e Intervall (sec)
@default e 10
rem Optionen
@param f Startverzögerung (in sec)
@default f 1
 
if a<1 then let a=1
if b<1 then let b=5
if c<2 then let c=5
if d<0 then let d=0
if e<0 then let e=0

t=d*60000+e*1000
f=f*1000
if c<1 then let c=1
if t<1000 then let t=1000

print "Programm P + 1xLöschtaste"
print "Gesamtzeit:", (t*c+f)/60000, "min", (t*c+f)%60000/1000, "sec"

if f>0 then print "Warte", f/1000, "secunden"
sleep f

let m=1
gosub "hdr"

for m=2 to c
  print "Warte", d, "min", e, "sec"
  sleep t
  gosub "hdr"
next m
print "Programm erfolgreich beendet"
end

:hdr
  print "Serie:",m
  print "Bild", 1, "von", b
  press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
  for s=2 to b
    for n=1 to a
      click "right"
    next n
    print "Bild", s, "von", b
    press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
  next s
  for t=1 to (b-1)
    sleep 100
    for s=1 to a
      click "left"
    next s
  next t
return


Hier läuft das Script zwar durch aber es hält die Intervallpausen nicht ein sondern läuft ohne Pause durch.
Hat jemand eine Idee wo hier und bei der Bewegungserkennung der Fehler ist ?
ixus55 allbest-ixus55_sd450-100b-51-425
pi23
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 2
Registriert: 22.06.2008, 14:37

Beitragvon msl » 24.06.2008, 20:48

Hallo,

gute Idee, eine Sammlung für diesen Sonderfall anzulegen. 8)

Mir ist aufgefallen, dass häufig
Code: Alles auswählen
release "shoot_half"
fehlt. Es sollte doch immer press mit release abgeschlossen werden. Ich habe aber noch nicht getestet, ob dies zwingend notwendig ist.

Gruß msl
■ "Hey you, don't tell me there's no hope at all. Together we stand, divided we fall."CHDK inside FAQCHDK-Neuigkeiten auf Twitter
Benutzeravatar
msl
Super-Mod
Super-Mod
 
Beiträge: 4510
Bilder: 271
Registriert: 22.02.2008, 12:47
Wohnort: Leipzig
Kamera(s): A720 1.00c
SX220 1.01a

Beitragvon holgi09 » 24.06.2008, 21:06

Ich glaube, da liegt der Hase begraben. Ich hatte bei meinen Scriptanpssungen auch den release "shoot_full" oder release "shoot_half" vergessen. Da wurde dann das Bild angezeigt und das Script lief nicht weiter.
Canon Digital Ixus 130, leider noch nicht portiert...
Benutzeravatar
holgi09
CHDK-Begeisterter
CHDK-Begeisterter
 
Beiträge: 144
Registriert: 13.06.2008, 09:04
Wohnort: 31xxx
Kamera(s): EOS 10D.

Beitragvon The-Holgi » 16.07.2008, 12:16

Hallo,
hat jemand das Script "Bewegungserkennung" auf einer Ixus 55 zum laufen bekommen ?
Bastel schon seit Stunden daran herum. Es startet erst ganz normal aber nach dem ersten Foto geht es nicht weiter.

Gruß Holgi
The-Holgi
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 2
Registriert: 27.06.2008, 21:57

Beitragvon The-Holgi » 17.07.2008, 09:57

Hi, habe das im englischen Forum gefunden. Geht ohne Probleme mit der Ixus55



Code: Alles auswählen
rem Author: fudgey - based on BarneyFive's MD Lightning6 and MLuna's Motion Detect scripts
rem Tested on A570IS, Allbest build 16
rem For bursts, set the camera in continuous shooting mode and set j>0
rem If j>0 in single shot mode, you will see your shot for j seconds on screen.
@title Fast MD with Burst/Preview 080205
@param a Columns
@default a 6
@param b Rows
@default b 4
@param c Threshold (0-255)
@default c 10
@param d Compare Interval (ms)
@default d 1
@param e Trigger Delay (0.1 sec)
@default e 42
@param f Rows to Exclude
@default f 0
@param g Pix-Step(speed/accuracy adj)
@default g 8
@param h Reg Mode(0-no,1-incl,2-excl)
@default h 0
@param i Measure Mode (1-Y,0-U,2-V)
@default i 1
@param j Burst/Preview (sec,0=off)
@default j 0
if a<1 then a=1
if b<1 then b=1
if c<0 then c=0
if g<1 then g=1
if f<1 then f=1
if j<0 then j=0
e=e*100
j=j*1000
print ">[";a;",";b;"] threshold: ";c
x=30000
if j>0 then goto "md_burst"
:md_singleshot
press "shoot_half"
t=0
do
md_detect_motion a, b, i, x, d, c, 1, t, h, 1, 1, a, f, 0, g, e
until t>0
click "shoot_full"
goto "md_singleshot"
:md_burst
press "shoot_half"
t=0
do
md_detect_motion a, b, i, x, d, c, 1, t, h, 1, 1, a, f, 0, g, e
until t>0
press "shoot_full"
let X=get_tick_count
:contloop
let U=get_tick_count
let V=(U-X)
if V<j then goto "contloop"
release "shoot_full" 
goto "md_burst"
Ixus 55, CHDK-allbest for ixus55_sd450 fw:100c build:51 date:Sun, 29 Jun 2008
The-Holgi
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 2
Registriert: 27.06.2008, 21:57

Beitragvon pterozaurus » 18.07.2008, 14:11

leider löst meine Ixus55 mit diesem Skript bei mir nach dem 1. ausgelösten Bild immer wieder grundlos aus.

Ich habe einem Skript die Befehle release "shoot_full" und release "shoot_half" mit erfolg eingesetzt.

Hier das ganze Skript:

Code: Alles auswählen
rem Developed on A570IS (Digic III) by fudgey. This variant may work on all Digic II cameras.
rem Allbest build 34 or higher (or compatible md_detect_motion) is required.
rem Digic III needs a small modification: "get_prop 205 p" -> "get_prop 206 p"
@title Fast MD Burst/Review + Mask 080411
@param a Columns
@default a 6
@param b Rows
@default b 4
@param c Threshold (0-255)
@default c 10
@param g Burst/Review time (s)
@default g 0
@param d Compare Interval (ms)
@default d 7
@param h Pixel Step (pixels)
@default h 6
@param f Channel (0U,1Y,2V,3R,4G,5B)
@default f 1
@param n Timeout (10s of seconds)
@default n 30
@param e Trigger Delay (0.1 sec)
@default e 5
@param i Masking (0=No 1=Mask 2=Use)
@default i 0
@param j Mask Columns Left
@default j 0
@param k Mask Columns Right
@default k 0
@param l Mask Rows Top
@default l 0
@param m Mask Rows Bottom
@default m 0
@param o Slow Shoot (0=No 1=Yes)
@default o 0
if a<1 then a=1
if b<1 then b=1
if i<0 then i=0
if i>2 then i=2
if j<0 then j=0
if k<0 then k=0
if l<0 then l=0
if m<0 then m=0
if j>a then j=a
if k>a then k=a
if l>b then l=b
if m>b then m=b
if g<0 then g=0
if f<0 then f=1
if f>5 then f=1
if f=0 then print "Channel: U chroma"
if f=1 then print "Channel: Luminance"
if f=2 then print "Channel: V chroma"
if f=3 then print "Channel: Red"
if f=4 then print "Channel: Green"
if f=5 then print "Channel: Blue"
if n<1 then n=1
e=e*100
g=g*1000
n=n*10000
if o>0 then goto "slow_md_loop"
:fast_md_loop
press "shoot_half"
t=0
do
  do
    get_prop 205 p
  until p=1
  md_detect_motion a, b, f, n, d, c, 1, t, i, j+1, l+1, a-k, b-m, 9, h, e
until t>0
let X=get_tick_count
:contloop1
let U=get_tick_count
let V=(U-X)
if V<g then goto "contloop1"
release "shoot_full"
release "shoot_half"
do
  get_prop 205 p
until p<>1
goto "fast_md_loop"
:slow_md_loop
t=0
do
  md_detect_motion a, b, f, n, d, c, 1, t, i, j+1, l+1, a-k, b-m, 0, h, e
until t>0
if g>1 then goto "contshoot2" else shoot
goto "slow_md_loop"
:contshoot2
press "shoot_full"
let X=get_tick_count
:contloop2
let U=get_tick_count
let V=(U-X)
if V<g then goto "contloop2"
release "shoot_full"
release "shoot_half"
do
  get_prop 205 p
until p<>1
goto "slow_md_loop"



folgende weitere Skripte laufen auf meiner Ixus55 einwandfrei:
ein weiteres BewegungsSkript (wurde von mir wie oben geändert):
Code: Alles auswählen
rem orig. Johan Van Barel 02-04-2008

@title Bewegungserkennung
@param a Spalten
@default a 6
@param b Reihen
@default b 4
rem Schwellwert: 10=Blitz, 12=sonnig, 24=wolkig, 36=dunstig
rem Der Schwellwert ist die Epfindlichkeit der Bewegungserkennung
rem Blitz steht für Gewitterfotografie
@param c Schwellwert(0-255)
@default c 24
@param d Interval (mSek.)
@default d 1
rem Verzögerung: 0=sehr schnell(Blitz), 16=normal, 32=langsam
@param e Verzögerung(.1 Sek.)
@default e 0
@param f Blockgröße
@default f 8
rem Modus U bzw.V=chroma Y=luma
@param g Modus(U=0,Y=1,V=2)
@default g 1
@param h Anfangsverzögerung (Sek.)
@default h 1

if a<1 then a=1
if b<1 then b=1
if c<0 then c=0
if e<0 then e=0
if f<1 then f=1
if g<0 then g=0
if g>5 then g=5
if r<0 then r=0
if h<0 then h=0

e=e*100

rem Startzeit in ms
x=5000

sleep h*1000

i=0
while 1
    t=0
    if e=0 then
        press "shoot_half"
        do
            rem Digic II 205 Digic III 206
            get_prop 205 p
        until p=1
    endif
    md_detect_motion a, b, g, x, d, c, 1, t, 0, 1, 1, a, b, 0, f, e
    if t>0 then
        click "shoot_full"
   sleep 250
   release "shoot_half"
        i=i+1
        print "Bild", i, "(Blocks="; t; ")"
        if e=0 then
            do
                rem Digic II 205 Digic III 206
                get_prop 205 p
            until p<>1
        endif
    endif
wend



Intervall für Zeitraffer (ebenfalls geändert wie oben beschrieben):
Code: Alles auswählen
rem Datei: intervall-foto.bas
rem Zweck: mehrere Fotos hintereinander aufnehmen

@title Intervall-Fotografie

@param a Zahl der Aufnahmen
@default a 10
@param b Intervall (min)
@default b 0
@param c Intervall (sec)
@default c 10

t=b*60000+c*1000

if a<2 then let a=10
if t<1000 then let t=1000

print "Gesamtzeit:", t*a/60000, "min", t*a%60000/1000, "sec"

sleep 1000

print "Aufnahme 1 von", a
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
release "shoot_half"
sleep 500
for n=2 to a
    print "Warte", b, "min", c, "sec"
    sleep t
    print "Aufnahme", n, "von", a
    press "shoot_half"
    sleep 1000
    press "shoot_full"
    sleep 1000
    release "shoot_full"
    release "shoot_half"
sleep 500
next n

end



Belichtungsreihe:
Code: Alles auswählen
@title Belichtungsreihe
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1

if a<1 then a=3
if b<1 then b=5
if c<0 then c=0

if c>0 then print "Warte", c, "Sekunden"
sleep c*1000

get_prop 25 x
y=-(a*b+a)*16
for s=1 to b
y=y+a*32
set_prop 25 y
set_prop 26 y
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"von",b,"mit",z","(y*10/32/3-z*10)*t,"EV"
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
release "shoot_half"
sleep 500
next s
set_prop 25 x
set_prop 26 x
end



und USB Auslöser (wurde ungeändert übernommen):
Code: Alles auswählen
@title Inverted Remote
@param a Burst/Review time (s)
@default a 0
@param b safety sleep (0.1 s)
@default b 3

if a<1 then a=100 else a=a*1000
if b<0 then b=0 else b=100*b

:presswait
do
until is_key "remote"
press "shoot_half"
sleep b
do
until not (is_key "remote")
press "shoot_full"
sleep a
release "shoot_full"
release "shoot_half"
sleep b
goto "presswait"



Ich hoffe das hilft schon mal weiter

Grüße
Stephan
SX220 HS; Fw. 101b; CHDK_DE 1.2.8 Rev. 2099
Ixus55:chdk ixus55_sd450-100c-1.0.0-DE
Benutzeravatar
pterozaurus
CHDK-Begeisterter
CHDK-Begeisterter
 
Beiträge: 65
Bilder: 0
Registriert: 18.06.2008, 11:41
Kamera(s): SX220 HS
Ixus 55

Beitragvon Wowbagger » 27.07.2008, 14:19

Hallo Forum!
Habe durch einen Freund von CHDK erfahren, und nun wollte ich das auch mal testen.
Aber zuerst muss ich mich mal bedanken. Habe mich schon reingelesen und viele nützliche Tipps gefunden. :)


Aber nun zu meiner Frage:

Ich habe beide oben erwähnten Bewegungserkennungs-Scripts getestet, jedoch ohne Erfolg.
Die Scripte starten, aber es wird kein Bild ausgelöst.

Ich habe jeweils im Manuellen Einzelbild-, als auch im Reihenmodus getestet. Eingestellt waren die Standardwerte.
Bin um jede Hilfe dankbar.
IXUS55
Wowbagger
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 7
Registriert: 27.07.2008, 13:41

Beitragvon fe50 » 27.07.2008, 15:21

Hallo & willkommen im Forum, Wowbagger !

probiere doch (noch)mal das 2. Script aus dem letzten Beitrag, im manuellen Modus, der Blitz muss deaktiviert (nicht auf Auto !) sein, dann sollte es klappen...
Du kannst auch noch testweise den Befehl "sleep 250" in "sleep 1000" abändern & testen, evtl. ist nur die Wartezeit zu kurz...
"The grass was greener, The light was brighter"►  ◄fe50 home►  ◄TRAIL-Magazin►  ◄RTFM !
Benutzeravatar
fe50
CHDK-Legende
CHDK-Legende
 
Beiträge: 1105
Registriert: 25.04.2008, 15:28
Wohnort: B'Württemberg
Kamera(s): Ixus50 101b, Ixus860 100c, SX10 101a

Beitragvon Wowbagger » 27.07.2008, 16:59

Hallo fe50!

Danke für deine Antwort! Aber leider funktioniert es immer noch nicht. :? Ich habe auch den von dir erwähnten Tipp mit der Verzögerung befolgt. Es taucht immer noch das selbe Problem auf. Das Script startet, aber die Kamera löst nicht aus.
Das ganze bei folgenden Einstellungen: Modus Manuell, Blitz deaktiviert, Script auf Standard.
Kann es sein, dass vielleicht noch irgendeine andere Einstellung das Problem auslöst?
IXUS55
Wowbagger
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 7
Registriert: 27.07.2008, 13:41

Beitragvon msl » 27.07.2008, 18:02

Hallo,

2 Fragen: Welche CHDK-Version verwendest Du? Funktionieren andere Skripte?

Vielleicht solltest Du erst mal etwas mit einem einfachen Skript experimentieren, um das Auslösen abzusichern. Bau Dir ein einfaches Skript, mit dem Du einfach auslösen kannst und per Parameter die Wartezeit bestimmen kannst. Das optimale Ergebnis kannst Du ja dann verwenden.

Gruß msl
■ "Hey you, don't tell me there's no hope at all. Together we stand, divided we fall."CHDK inside FAQCHDK-Neuigkeiten auf Twitter
Benutzeravatar
msl
Super-Mod
Super-Mod
 
Beiträge: 4510
Bilder: 271
Registriert: 22.02.2008, 12:47
Wohnort: Leipzig
Kamera(s): A720 1.00c
SX220 1.01a

Beitragvon Wowbagger » 27.07.2008, 18:48

Hallo msl,

ich verwende AllBest #50 mit einer 1.00C Firmware.

Ich habe schon mit anderen Scripten experimentiert, unteranderem einem von CHDFLover, um Belichtungsreihen zu erstellen.

Code: Alles auswählen
rem Belichtungsreihe mit fix Fokus
rem fuer digicII, getestet auf IXUS 700
rem Originalscript von CHDKLover, msl http://forum.chdk-treff.de/viewtopic.php?t=171#857
rem erweitert von stefstef

@title HDR [Anm. Den Titel habe ich Umbenannt]
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1

rem Ueberpruefung mind. 1 EV Step
if a<1 then a=3
rem Ueberpruefung auf mehr als 1 Bild
if b<1 then b=5
rem keine neg. Verzögerung
if c<0 then c=0

if c>0 then print "Warte", c, "secunden"
sleep c*1000

rem Belichtungskorrektur lesen und in u,v speichern
get_prop 25 u
get_prop 26 v

rem fokussieren und Fokus speichern
press "shoot_half"
sleep 2000
get_focus q
release "shoot_half"

y=-(a*b+a)*16
for s=1 to b
y=y+a*32
rem Belichtungskorrektur setzen
set_prop 25 y
set_prop 26 y
rem Fokus pruefen und ggf. auf ermittelten Wert setzen
get_focus r
if r<>q then
set_focus q
endif
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
click "shoot_full"
rem ...warten, bis das Bild gespeichert ist
do
get_prop 205 w
until w=1
do
get_prop 205 w
until w<>1
next s

rem urspruengliche Belichtungskorrektur wieder herstellen
set_prop 25 u
set_prop 26 v
end


Dieses läuft ohne Probleme durch.

Da ich im Moment noch neu bei der ganzen Sache bin, muss ich mich ersteinmal mit dem scripten beschäftigen. Da ist ein einfaches Script bauen schon eine Herrausforderung ;)

edit: Habe ein Update auf AllBest 50 gemacht.
edit²: Juhuu! Nach dem Update läuft das Script durch! :)

Danke für eure Hilfe!
IXUS55
Wowbagger
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 7
Registriert: 27.07.2008, 13:41

Beitragvon didi » 27.07.2008, 19:09

hallo,

du sollest aus deinem script die zeile 1- 5 löschen.

mfg didi
Powershot a720 IS mit CHDK-DE-Version
- CHDK Fernbedienung mit 3 Tasten -
Benutzeravatar
didi
CHDK-Begeisterter
CHDK-Begeisterter
 
Beiträge: 116
Registriert: 19.04.2008, 15:24
Wohnort: Petershagen / OWL
Kamera(s): Powershot A720 1.0c

Beitragvon Wowbagger » 27.07.2008, 19:49

Hallo didi,

ja ich hatte schon in einem anderen Thread von dem Problem mit den ersten Zeilen gelesen.
Sollte ich sie nun zur Sicherheit, trotz des nun funktionierenden scripts löschen?
IXUS55
Wowbagger
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 7
Registriert: 27.07.2008, 13:41

Beitragvon msl » 27.07.2008, 21:23

Skripte sollten nicht mit einer Leerzeile beginnen, aber mit einer Leerzeile enden.

Wenn Dein Skript funktioniert, brauchst Du nichts zu ändern.

Gruß msl
■ "Hey you, don't tell me there's no hope at all. Together we stand, divided we fall."CHDK inside FAQCHDK-Neuigkeiten auf Twitter
Benutzeravatar
msl
Super-Mod
Super-Mod
 
Beiträge: 4510
Bilder: 271
Registriert: 22.02.2008, 12:47
Wohnort: Leipzig
Kamera(s): A720 1.00c
SX220 1.01a

Beitragvon Wowbagger » 30.07.2008, 23:12

Hallo,

nach einigen Tests habe ich nun festgestellt, dass das script ziemlich langsam auslöst.
Wenn ich zB mit dem Finger gemütlich durch das Bild "fliege" ist auf dem entstandenen Foto mein Finger nicht mehr zu sehen - im besten Fall nur noch ein verwaschener Schatten.
Auch normale Aufnahmen von sich bewegenden Personen im Raum sind nur unscharf und verzögert möglich.

Ich verwende das script zweite script aus pterozaurus´ Beitrag weiter oben. Auch Änderungen an den Empfindlichkeitsstufen brachten keinen Erfolg.

Hat vielleicht irgendwer eine Idee?

mfg

wowbagger
IXUS55
Wowbagger
CHDK-Einsteiger
CHDK-Einsteiger
 
Beiträge: 7
Registriert: 27.07.2008, 13:41

Nächste

Zurück zu Code-Ecke

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste