[uBasic] Belichtungsreihen-Skript mit fixed Fokus für DigicII

[stefstef]

Hallo,

ich habe das Belichtungsreihen-Script von msl ein wenig erweitert, so dass zu Beginn der Reihe einmal automatisch fokussiert wird und danach der Fokus innerhalb der Belichtungsreihe immer gleich bleibt - auch bei Kameras, die nicht über eine manuelle Einstellmöglichkeit verfügen.

Getestet habe ich mit einer IXUS 700, dort funktionieren die Einstellungen. Ich bin mir nicht sicher, ob ("get_prop 205 w") auf allen DIGICII Kameras funktioniert und wäre dankbar für Feedback.

Code: Alles auswählen

rem Belichtungsreihe mit fix Fokus
rem fuer digicII, getestet auf IXUS 700
rem Originalscript von CHDKLover, msl http://forum.chdk-treff.de/viewtopic.php?t=171#857
rem erweitert von stefstef

@title Belichtungsreihe fix Fokus
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1

rem Ueberpruefung mind. 1 EV Step
if a<1 then a=3
rem Ueberpruefung auf mehr als 1 Bild
if b<1 then b=5
rem keine neg. Verzögerung
if c<0 then c=0

if c>0 then print "Warte", c, "secunden"
sleep c*1000

rem Belichtungskorrektur lesen und in u,v speichern
get_prop 25 u
get_prop 26 v

rem fokussieren und Fokus speichern
press "shoot_half"
sleep 2000
get_focus q
release "shoot_half"

y=-(a*b+a)*16
for s=1 to b
  y=y+a*32
rem Belichtungskorrektur setzen
  set_prop 25 y
  set_prop 26 y
rem Fokus pruefen und ggf. auf ermittelten Wert setzen
  get_focus r
  if r<>q then
    set_focus q
  endif
  z=y/32/3
  if z<0 then t=-1 else t=1
  print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
  click "shoot_full"
rem ...warten, bis das Bild gespeichert ist
  do
    get_prop 205 w
  until w=1
  do
    get_prop 205 w
  until w<>1
next s

rem urspruengliche Belichtungskorrektur wieder herstellen
set_prop 25 u
set_prop 26 v
end


Edit (2008/04/30): Erfolgreich getestet mit: IXUS 700, A610

Dank an CHDKLover, msl, ~Aeropic~ und alle, die an den Property_Case_values arbeiten!
stefstef

[gehtnix]

Genial stefstef!

Habe es auf meiner A610 probiert, und läuft.

Anmerkung für die Code-Spezialisten!
Einmal als ANSI gespeichert, und das Skript läuft.
Als UTF gespeichert, werden die Umlaute fehlerhaft dargestellt.
Das Skript läuft nicht und zeigt folgenden Fehler:
üBasic: 1 Unk stmt

grüße gehtnix

[stefstef]

Hallo gehtnix,

danke erst mal für's testen!

Bei meiner IXUS 700 ist mir aufgefallen, dass sich unter manchen Lichtverhältnissen die Blende innerhalb der Reihe ändert, was natürlich nicht erwünscht ist (Änderung der Tiefenschärfe). Leider habe ich aber bis jetzt nichts gefunden, unter welchen Umständen man das reproduzierbar machen kann. Bei einem Versuch eine Belichtungsreihe für eine HDR-Aufnahmen mit Wolken zu machen scheinen die Chancen recht hoch zu sein.

Es wäre schön, wenn Du das mal irgendwann testen könntest...

stefstef

[msl]

Hallo stefstef,

was hälst Du davon, den Blendenwert (Av) auszulesen und fest zu definieren?

Kennst Du diese PropertyCase-Seite? Außerdem gibt es hier auch noch Hinweise, die helfen könnten.

Gruß msl

[stefstef]

Hallo msl,

gute Idee - wenn man dann ausschließlich die Belichtungszeit variiert, sollte das für HDR ziemlich gute Ergebnisse liefern...

Ich schaue mal, ob ich in den nächsten Tagen etwas in diese Richtung erstellen kann.

stefstef

[gehtnix]

Hi Stefstef,

ich gerade nochmal den Versuch gemacht.
Eingestellt AV, Blende 8, Blitz aus und dann im dunklen Raum halb gedrückt.
Die Kamera schaltet dann selber auf Blende 2,8, und nur 1 Sek und der rote Warnhinweis erscheint.
Das ist normal und korrekt. Im Modus AV scheint bei 1 Sekunde Schluß zu sein.
So könnte es sein dass man in einer Belichtungsreihe in so einen Grenzbereich reinfährt und die Kamera schaltet dann eben automatisch die Blende um.
Mit dem Gedanken von MSL stellt sich aber dann doch auch die Frage, komme ich dann nicht in irgendeiner Situation an die zeitliche Grenze?

Und nachträglich noch eingefügt, MSL hat das eben auch festgestellt wie ich jetzt 2 Mausklicks später las.

Grüße gehtnix

[msl]

Ich würde generell für solche Sachen den manuellen Modus wählen. Hier läuft man nicht Gefahr, dass Automatiken eingreifen, siehe Av-Modus - Belichtungszeit < 1 Sekunde.

Gruß msl

[stefstef]

Der manuelle Modus ist für solche Versuche natürlich die erste Wahl.

Hier läuft man nicht Gefahr, dass Automatiken eingreifen, siehe Av-Modus - Belichtungszeit < 1 Sekunde.

Mit dem Gedanken von MSL stellt sich aber dann doch auch die Frage, komme ich dann nicht in irgendeiner Situation an die zeitliche Grenze?

Ist Richtig - in einigen Situationen (bei einigen Einstellungen) wird man keine verwertbaren Bilder erhalten. Ich vermute aber, dass die möglichen Verschlußzeiten einen recht weiten Spielraum geben, in dem man testen kann.

Leider ist die IXUS 700 in dieser Hinsicht hochautomatisiert . Manueller Modus bedeutet dort leider nicht Blenden oder Zeitwahl, sondern die Wahl bestimmter Belichtungsprogramme... (Die übrigens meist sehr gute Ergebnisse liefern!)

Ich habe zwar am Wochenende nicht übermäßig viel Zeit mit der Blendenvorwahl verbringen können, bin aber immer wieder von der Programmautomatik überrumpelt worden - da muß ich noch einiges testen...

[Gast]

Hallo,

ich habe Dein Skript ausprobiert und es hat auch ab und zu funktioniert.


Aber dann bricht es immer wieder beim Speichern des 2. Fotos ab und das Objektiv wird zur Hälfte eingezogen.


Weiss jemand Rat? Habe das CHDK#50

Gruss,

M

[stefstef]

Hallo,

Aber dann bricht es immer wieder beim Speichern des 2. Fotos ab und das Objektiv wird zur Hälfte eingezogen.

Es könnte sein, dass dieser Codeschnipsel Probleme macht:

Code: Alles auswählen

rem ...warten, bis das Bild gespeichert ist
  do
    get_prop 205 w
  until w=1
  do
    get_prop 205 w
  until w<>1


Bitte ersetze diese Zeilen mal durch

Code: Alles auswählen

sleep 5000

bzw. passe die 5000 auf die Zeit an, die Kamera in etwa benötigt, um das Bild zu speichern. Das macht das Skript zwar langsamer, aber sollte einen sicheren Ablauf bis zum Ende ermöglichen.

Stefstef

[Gast]

Der Austausch der Zeilen hat leider keinen Effekt.

Oder habe ich es falsch eingebaut(?):

sieht nun so aus:

print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
click "shoot_full"
sleep 5000
next s

rem urspruengliche Belichtungskorrektur wieder herstellen
set_prop 25 u
set_prop 26 v
end


Gruß,



M

[msl]

@Osolemirnix

Mach doch bitte mal Angaben zur verwendeten Kamera und Modus. Das ist hilfreich, um eine Fehleranalyse zu machen.

Gruß msl

[stefstef]

Der Austausch der Zeilen hat leider keinen Effekt.

Code: Alles auswählen

  print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
  click "shoot_full"
sleep 5000
next s


Das sieht erst mal so aus, wie ich mir das gedacht hatte...

Nur zur Sicherheit, dass ich richtig verstanden habe:
- Das Skript startet
- Die Kamera fokussiert (Der Fokus wird erstmalig bestimmt)
- nach ca. 2 Sek. wird der ermittelte Fokus eingestellt
- "Bild....." erscheint auf dem Display
- Das Bild wird aufgenommen und gespeichert
- Der ermittelte Fokus wird eingestellt
- "Bild....." erscheint auf dem Display
- Das Bild wird aufgenommen und die Kamera schaltet sich während des Speicherns aus?

Stefstef

[Gast]

Hallo Stefstef,


Du hast es richtig beschrieben.

Beim genauen Beobachten des Vorgangs ist mir aufgefallen:

- Das Geräusch des Auslösens ist normalerweise ein Doppelklicken.

- In diesem speziellem Fall bricht das Klicken ab und das Display wird schwarz und das Objektiv fährt nicht ganz zurück - ob das nun beim Speichern oder schon bei der Aufnahme passiert, kann ich nicht sicher sagen.

@msl:

Ich habe eine Powershot S2 IS und habe es in mehreren Modi versucht M, AV, P, TV mit dem gleichen Ergebnis


Gruß,

M.

[msl]

Die CHDK-Software stürzt ja offensichtlich bei dem Vorgang ab.

Wenn nicht schon gemacht, würde ich mal CHDK komplett neu auf die Karte kopieren. Vielleicht hat sich nur ein Kopierfehler eingeschlichen.

Gruß msl