EDIT am 11.03.09 Folgendes Script-Sevenup ist der Nachfolger und hat mehr Funktionsumfang.
um die Akkustandzeit bei Intervallaufnahmen zu erhöhen habe ich
ein bestehendes Intervall-Skript dahingehend angepasst.
Bei Digic III Cameras muß nachfolgend get_prop von 181 auf 105 abgeändert werden!
Man kann mit dem Parameter f festlegen wieviel Bilder am Anfang auf dem LCD angezeigt werden.
Danach schaltet der LCD ab. Er schaltet sich aber rechtzeitig vor dem Ende der Intervallreihe automatisch wieder ein. Dann werden f Fotos am Schluß noch angezeigt.
Beipiel mit 200 Fotos und f=5, 5 Aufnahmen mit LCD, 190 Aufnahmen mit abgeschaltetem LCD und die restlichen 5 Bilder wieder mit eingschaltetem LCD.
Folgenden Parameter habe ich hinzugefügt:
@param f LCD aus
@default f 5
Das kam in der Schleife dazu:
Schaltet den LCD nicht ab wenn zu wenig Bilder gemacht werden
if s<=(f*2) then goto "weiter"
Zum Abschalten des LCD
if i=(f+1) then
do
click "display"
get_prop 181 u
until (u=2 or u=3)
endif
Zum Einschalten des LCD
if i=(s-f+1) then
do
click "display"
get_prop 181 u
until u=x
endif
:weiter
Das komplette Skript:
- Code: Alles auswählen
@title Intervall-Foto-LCD aus
@param a Anzahl Bilder (Faktor 100)
@default a 0
@param b Anzahl Bilder (Faktor 10)
@default b 1
@param c Anzahl Bilder (Faktor 1)
@default c 0
@param d Intervall (min)
@default d 0
@param e Intervall (sec)
@default e 1
@param f LCD aus nach x Bildern
@default f 5
get_prop 181 x
u=x
t=d*60000+e*1000
if a<0 then let a=0
if b<0 then let b=0
if c<0 then let c=0
if t<1000 then let t=1000
s=a*100+b*10+c
print "Gesamtzeit:", t*s/60000, "min", t*s%60000/1000, "sec"
sleep 1000
print "Bild 1 von", s
shoot
for i=2 to s
if s<=(f*2) then goto "weiter"
if i=(f+1) then
do
click "display"
get_prop 181 u
until (u=2 or u=3)
endif
if i=(s-f+1) then
do
click "display"
get_prop 181 u
until u=x
endif
:weiter
print "Warte", d, "min", e, "sec"
sleep t
print "Bild", i, "von", s
shoot
next i
end
Zum Schluß hätte ich gern noch ein Frage beantwortet bekommen:
Mit set_prop 181 konnte ich das Vorhaben nicht lösen.
Hat das seine Richtigkeit?
Tester werden gern gesehen!
Wenn das Skript OK ist könnte das ja in die Sammlung aufgenommen werden
EDIT: Ein paar Kleinigkeiten geändert. Bis auf den Titel ist das Skript geblieben!
EDIT: am 11.7.08 "until u=2" auf "until (u=2 or u=3) geändert. Dank an PhyrePhoX
gruß gehtnix