Die Lösung bei manchen Scripts den "Shoot" Befehl durch:
- Code: Alles auswählen
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
ersetzen.
Das hat bei mir bei folgenden Scripts funktioniert.
- Code: Alles auswählen
@title Intervall-Fotografie
@param a Zahl der Aufnahmen
@default a 100
@param b Intervall (Min.)
@default b 0
@param c Intervall (Sek.)
@default c 1
t=b*60000+c*1000
if a<2 then let a=10
if t<1000 then let t=1000
print "Gesamtzeit:", t*a/60000, "Min.", t*a%60000/1000, "Sek."
sleep 1000
print "Aufnahme 1 von", a
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
for n=2 to a
print "Warte", b, "Min.", c, "Sek."
sleep t
print "Aufnahme", n, "von", a
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
next n
end
- Code: Alles auswählen
@title Belichtungsreihe
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1
if a<1 then a=3
if b<1 then b=5
if c<0 then c=0
if c>0 then print "Warte", c, "Sekunden"
sleep c*1000
get_prop 25 x
y=-(a*b+a)*16
for s=1 to b
y=y+a*32
set_prop 25 y
set_prop 26 y
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"von",b,"mit",z","(y*10/32/3-z*10)*t,"EV"
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
release "shoot_half"
sleep 500
next s
set_prop 25 x
set_prop 26 x
end
- Code: Alles auswählen
@title Belichtungsreihe fix Fokus
@param a Stellweite (a*1/3EV)
@default a 3
@param b Anzahl Fotografien
@default b 5
@param c Startverzögerung (in sec)
@default c 1
rem Ueberpruefung mind. 1 EV Step
if a<1 then a=3
rem Ueberpruefung auf mehr als 1 Bild
if b<1 then b=5
rem keine neg. Verzögerung
if c<0 then c=0
if c>0 then print "Warte", c, "secunden"
sleep c*1000
rem Belichtungskorrektur lesen und in u,v speichern
get_prop 25 u
get_prop 26 v
rem fokussieren und Fokus speichern
press "shoot_half"
sleep 2000
get_focus q
release "shoot_half"
y=-(a*b+a)*16
for s=1 to b
y=y+a*32
rem Belichtungskorrektur setzen
set_prop 25 y
set_prop 26 y
rem Fokus pruefen und ggf. auf ermittelten Wert setzen
get_focus r
if r<>q then
set_focus q
endif
z=y/32/3
if z<0 then t=-1 else t=1
print "Bild",s,"/",b,"->",z","(y*10/32/3-z*10)*t,"EV"
rem Bild ausloesen und...
click "shoot_full"
rem ...warten, bis das Bild gespeichert ist
do
get_prop 205 w
until w=1
do
get_prop 205 w
until w<>1
next s
rem urspruengliche Belichtungskorrektur wieder herstellen
set_prop 25 u
set_prop 26 v
end
Nun zu den Scripts bei denen es (noch) nicht geht.
- Code: Alles auswählen
@title Bewegungserkennung
@param a Spalten
@default a 6
@param b Reihen
@default b 4
rem Schwellwert: 10=Blitz, 12=sonnig, 24=wolkig, 36=dunstig
rem Der Schwellwert ist die Epfindlichkeit der Bewegungserkennung
rem Blitz steht für Gewitterfotografie
@param c Schwellwert(0-255)
@default c 24
@param d Interval (mSek.)
@default d 1
rem Verzögerung: 0=sehr schnell(Blitz), 16=normal, 32=langsam
@param e Verzögerung(.1 Sek.)
@default e 0
@param f Blockgröße
@default f 8
rem Modus U bzw.V=chroma Y=luma
@param g Modus(U=0,Y=1,V=2)
@default g 1
@param h Anfangsverzögerung (Sek.)
@default h 1
if a<1 then a=1
if b<1 then b=1
if c<0 then c=0
if e<0 then e=0
if f<1 then f=1
if g<0 then g=0
if g>5 then g=5
if r<0 then r=0
if h<0 then h=0
e=e*100
rem Startzeit in ms
x=5000
sleep h*1000
i=0
while 1
t=0
if e=0 then
press "shoot_half"
do
rem Digic II 205 Digic III 206
get_prop 205 p
until p=1
endif
md_detect_motion a, b, g, x, d, c, 1, t, 0, 1, 1, a, b, 0, f, e
if t>0 then
click "shoot_full"
sleep 1000
release "shoot_full"
i=i+1
print "Bild", i, "(Blocks="; t; ")"
if e=0 then
do
rem Digic II 205 Digic III 206
get_prop 205 p
until p<>1
endif
endif
wend
Hier wird einaml ausgelößt dann bleibt das Script stehen. Wo liegt der Fehler?
Und Hier:
- Code: Alles auswählen
@title Intervall_HDR
rem HDR_Param
@param a HDR_Stellweite
@default a 3
@param b Anzahl Fotografien max. 13
@default b 5
rem Intevall_Param
@param c Zahl der Aufnahmen
@default c 3
@param d Intervall (min)
@default d 0
@param e Intervall (sec)
@default e 10
rem Optionen
@param f Startverzögerung (in sec)
@default f 1
if a<1 then let a=1
if b<1 then let b=5
if c<2 then let c=5
if d<0 then let d=0
if e<0 then let e=0
t=d*60000+e*1000
f=f*1000
if c<1 then let c=1
if t<1000 then let t=1000
print "Programm P + 1xLöschtaste"
print "Gesamtzeit:", (t*c+f)/60000, "min", (t*c+f)%60000/1000, "sec"
if f>0 then print "Warte", f/1000, "secunden"
sleep f
let m=1
gosub "hdr"
for m=2 to c
print "Warte", d, "min", e, "sec"
sleep t
gosub "hdr"
next m
print "Programm erfolgreich beendet"
end
:hdr
print "Serie:",m
print "Bild", 1, "von", b
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
for s=2 to b
for n=1 to a
click "right"
next n
print "Bild", s, "von", b
press "shoot_half"
sleep 1000
press "shoot_full"
sleep 1000
release "shoot_full"
next s
for t=1 to (b-1)
sleep 100
for s=1 to a
click "left"
next s
next t
return
Hier läuft das Script zwar durch aber es hält die Intervallpausen nicht ein sondern läuft ohne Pause durch.
Hat jemand eine Idee wo hier und bei der Bewegungserkennung der Fehler ist ?